اصنع ريموت كنترول 7 قنوات للتحكم بالقارب الاسلكى او الطائرة المجنحة او سيارات السباق السريعة

اصنع ريموت كنترول 7 قنوات للتحكم بالقارب الاسلكى او الطائرة المجنحة او سيارات السباق السريعة

الكاتب : ASHRAF ALI التاريخ : الخميس، 14 يناير 2021 التعليقات : 66

مشروع انشاء ريموت كونترول 7 قنوات للتحكم عن بعد في القوارب اللاسلكية وغيرها من المجسمات المختلفة

الجزء الاول

في هذا المقال سوف نتحدث عن المرسل

انظر الروابط اسفل الفيديو ويمكنك طرح الأسئلة للمناقشة وتبادل المعلومات ليستفيد الجميع

والان مع شرح مفصل للمشروع

اولا تجهيز لوحة المرسل للعمل عليها

لصق الورقة المطبوعة على اللوحة

استخدام المكواة للطباعة على اللوحة

نزع الورق من على اللوحة

وضعها بمحلول كلوريد الحديديك

تنظيف مادة الطباعة من على اللوحة

ثقب اماكن القطع الالكترونية

اللحام وتثبيت القطع

فحص اللحامات

وضع القطع على اللوحة

 توصيل لوحة الاردوينو بالكمبيوتر لنقل الكود البرمجي

نقل الكود الى الاردوينو

اعادة لوحة الاردوينو الى الجهاز بعد تثبيت الكود البرمجي عليها

عمل علبة لتثبيت الأجزاء الالكترونية بشكل صحيح

تجربة لوحة المرسل

في هذه المرحة نقوم بتكرار ما سبق من التجهيز والطباعة وازالت النحاس والثقب ولحام المكونات واخيرا تثبيت الكود

البرمجي على لوحة الأردوينو ومن ثم يتم تركيبها على جهاز المستقبل ويمكنكم متابعة الصور التوضيحية لباقي المشروع

روابط هامه 

رابط شراء nrf


رابط شراء عصى التحكم اضغط هنا


رابط شراء الاردوينو نانو


رابط شراء سيرفو موتور اضغط هنا

_______

طباعة البرده اضغط بالاسفل

مخطط جاهز للطباعة ملف pdf المرسل اضغط هنا

مخطط توضيح اسماء و تركيب القطع اضغط هنا

مخطط جاهز للطباعة ملف pdf المستقبل اضغط هنا

الصورة التوضيحية للكباري للمستقبل

--------------------------------------------------

الكود البرمجي المرسل

-------------------------------------    

/*

    GND    ->   GND

    Vcc    ->   3.3V

    CE     ->   D9

    CSN    ->   D10

    CLK    ->   D13

    MOSI   ->   D11

    MISO   ->   D12

This code transmits 7 channels with data from pins A0, A1, A2, A3, D2 and D3

*/

#include <SPI.h>

#include <nRF24L01.h>

#include <RF24.h>

const uint64_t my_radio_pipe = 0xE8E8F0F0E1LL; //Remember that this code should be the same for the receiver

RF24 radio(9, 10);  //Set CE and CSN pins

// The sizeof this struct should not exceed 32 bytes

struct Data_to_be_sent {

  byte ch1;

  byte ch2;

  byte ch3;

  byte ch4;

  byte ch5;

  byte ch6;

  byte ch7;

};

//Create a variable with the structure above and name it sent_data

Data_to_be_sent sent_data;

void setup()

{

  radio.begin();

  radio.setAutoAck(false);

  radio.setDataRate(RF24_250KBPS);

  radio.openWritingPipe(my_radio_pipe);

  //Reset each channel value

  sent_data.ch1 = 127;

  sent_data.ch2 = 127;

  sent_data.ch3 = 127;

  sent_data.ch4 = 127;

  sent_data.ch5 = 0;

  sent_data.ch6 = 0;

  sent_data.ch7 = 127;

}

/**************************************************/

void loop()

{

  /*If your channel is reversed, just swap 0 to 255 by 255 to 0 below

  EXAMPLE:

  Normal:    data.ch1 = map( analogRead(A0), 0, 1024, 0, 255);

  Reversed:  data.ch1 = map( analogRead(A0), 0, 1024, 255, 0);  */

  

  sent_data.ch1 = map( analogRead(A0), 0, 1024, 0, 255);

  sent_data.ch2 = map( analogRead(A1), 0, 1024, 0, 255);

  sent_data.ch3 = map( analogRead(A2), 0, 1024, 0, 255);

  sent_data.ch4 = map( analogRead(A3), 0, 1024, 0, 255);

  sent_data.ch5 = digitalRead(2);

  sent_data.ch6 = digitalRead(3);

  sent_data.ch7 = map( analogRead(A4), 0, 1024, 0, 255);

  radio.write(&sent_data, sizeof(Data_to_be_sent));

}

----------------------------------------------------------------------------------------------------------------------------

الكود البرمجي المستقبل

----------------------------------        

/*

    GND    ->   GND

    Vcc    ->   3.3V

    CE     ->   D9

    CSN    ->   D10

    CLK    ->   D13

    MOSI   ->   D11

    MISO   ->   D12

This code receive 7 channels and create a PWM output for each one on D2, D3, D4, D5, D6, D7and D8

*/

#include <SPI.h>

#include <nRF24L01.h>

#include <RF24.h>

#include <Servo.h>  //To create PWM signals we need this lybrary

const uint64_t pipeIn = 0xE8E8F0F0E1LL;     //Remember that this code is the same as in the transmitter

RF24 radio(9, 10);  //CSN and CE pins

// The sizeof this struct should not exceed 32 bytes

struct Received_data {

  byte ch1;

  byte ch2;

  byte ch3;

  byte ch4;

  byte ch5;

  byte ch6;

  byte ch7;

};

Received_data received_data;

Servo channel_1;

Servo channel_2;

Servo channel_3;

Servo channel_4;

Servo channel_5;

Servo channel_6;

Servo channel_7;

int ch1_value = 0;

int ch2_value = 0;

int ch3_value = 0;

int ch4_value = 0;

int ch5_value = 0;

int ch6_value = 0;

int ch7_value = 0;

void reset_the_Data() 

{

  // 'safe' values to use when NO radio input is detected

  received_data.ch1 = 127;      //Throttle (channel 1) to 0

  received_data.ch2 = 127;

  received_data.ch3 = 127;

  received_data.ch4 = 127;

  received_data.ch5 = 0;

  received_data.ch6 = 0;

  received_data.ch7 = 0;

}

/**************************************************/

void setup()

{

  //Attach the servo signal on pins from D2 to D8

  channel_1.attach(3);

  channel_2.attach(8);

  channel_3.attach(4);

  channel_7.attach(5);

  channel_5.attach(6);

  channel_6.attach(7);

  channel_4.attach(2);

  

  //We reset the received values

  reset_the_Data();

  //Once again, begin and radio configuration

  radio.begin();

  radio.setAutoAck(false);

  radio.setDataRate(RF24_250KBPS);  

  radio.openReadingPipe(1,pipeIn);

  

  //We start the radio comunication

  radio.startListening();

}

/**************************************************/

unsigned long lastRecvTime = 0;

//We create the function that will read the data each certain time

void receive_the_data()

{

  while ( radio.available() ) {

  radio.read(&received_data, sizeof(Received_data));

  lastRecvTime = millis(); //Here we receive the data

}

}

/**************************************************/

void loop()

{

  //Receive the radio data

  receive_the_data();

//////////This small if will reset the data if signal is lost for 1 sec.

/////////////////////////////////////////////////////////////////////////

  unsigned long now = millis();

  if ( now - lastRecvTime > 1000 ) {

    // signal lost?

    reset_the_Data();

    //Go up and change the initial values if you want depending on

    //your aplications. Put 0 for throttle in case of drones so it won't

    //fly away

  } 

  

  ch1_value = map(received_data.ch1,127,0,1000,2000);

  ch2_value = map(received_data.ch2,127,0,1000,2000);

  ch3_value = map(received_data.ch3,127,0,1000,2000);

  ch4_value = map(received_data.ch4,127,0,1000,2000);

  ch5_value = map(received_data.ch5,0,1,1000,2000);

  ch6_value = map(received_data.ch6,0,1,1000,2000);

  ch7_value = map(received_data.ch7,0,255,1000,2000);

  //Creathe the PWM signals

  channel_1.writeMicroseconds(ch1_value);  

  channel_2.writeMicroseconds(ch2_value);  

  channel_3.writeMicroseconds(ch3_value);  

  channel_4.writeMicroseconds(ch4_value);  

  channel_5.writeMicroseconds(ch5_value);  

  channel_6.writeMicroseconds(ch6_value);  

  channel_7.writeMicroseconds(ch7_value);  

  

  

}//Loop end

فيسبوك توتير جوجل + لينكدان بينتريست

ASHRAF ALI

الكاتب : ASHRAF ALI

مواضيع مهمة أيضا